Este fórum está sendo desativado

[Diego100ges]

Bom dia pessoal,
Utilizo esse código para copiar alguns arquivos pdf de uma determinada origem para determinado destino, são em torno de 15 linhas, cada uma com uma origem diferente, então as vezes pode acontecer de alguma delas estar com o caminho errado, gostaria de saber se é possivel colocar na macro um aviso de qual linha deu erro, caso ocorra.

Código: Selecionar todos

Sub SalvarRelatorios()

    Dim origem  As String
    Dim destino As String
    Dim i       As Integer
    Dim Row     As Integer

Row = Plan1.Range("A" & Rows.Count).End(xlUp).Row

For i = 4 To Row
    origem = Range("C" & i)
    destino = Range("D" & i)
    FileCopy origem, destino
Next
End Sub

[Jimmy]

Olá Diego,

Veja se isto te ajuda:

Código: Selecionar todos

Sub SalvarRelatorios()

    Dim origem  As String
    Dim destino As String
    Dim Msg     As String
    Dim i       As Integer
    Dim Row     As Integer

Row = Plan1.Range("A" & Rows.Count).End(xlUp).Row

For i = 4 To Row
    origem = Range("C" & i)
    destino = Range("D" & i)
    On Error Resume Next
    FileCopy origem, destino

    If Err.Number <> 0 Then _
        Msg = Msg & "De:    " & origem & vbCrLf & "Para: " & destino & vbCrLf & _
                    "Linha " & i & ", Erro " & Err.Number & ": " & Err.Description & vbCrLf & vbCrLf
        on error goto 0
Next
If Msg <> "" Then MsgBox "Erro ao copiar o(s) arquivo(s):" & vbCrLf & vbCrLf & Msg
End Sub

Se esta mensagem colabora para a solução do problema, peço que dê um Like, clicando no botão com o "positivo", acima e a direita.

Jimmy San Juan

[Diego100ges]

Como uma luva Jimmy, muito obrigado!