Este fórum está sendo desativado

[AlanBC]

ola... boa noite.

preciso de uma macro pra abrir uma outra pasta de trabalho... assim,

estou com a pasta de trabalho "A" aberta e quero abrir a pasta de trabalho "B". mas se esta outra pasta de trabalho "B" já estiver aberta, somente vai selecionar a plan1 da pasta "B".
consegui fazer abrir a pasta "B" com Workbooks.Open "C:\...Cópia.xlsm"
mas retornar pra "B" depois de aberta nao consegui.

no aguardo.
obrigado.

[babdallas]

Veja se ajuda

Código: Selecionar todos

Option Explicit
Public Sub AbrirPastaTrabalho()
    Const strNomeArq As String = "Cronograma_Cursos.xlsx"
    Const strCaminho As String = "D:\Cursos"
    Dim wbk As Workbook
    
    If PastaAberta(strNomeArq:=strNomeArq) Then
        Workbooks(strNomeArq).Worksheets(1).Range("A1").Activate
    Else
        Set wbk = Workbooks.Open(Filename:=strCaminho & "\" & strNomeArq)
        wbk.Worksheets(1).Range("A1").Activate
    End If
End Sub


Private Function PastaAberta(strNomeArq As String) As Boolean
    Dim wbk     As Workbook
    Dim lngCont As Long
    
    For Each wbk In Application.Workbooks
        If wbk.Name = strNomeArq Then
            PastaAberta = True
            lngCont = lngCont + 1
        End If
    Next wbk
    
    If lngCont = 0 Then PastaAberta = False
End Function

[AlanBC]

bom dia!!!
exatamente o que queria!
perfeito!!!
muito obrigado babdallas!
abraço a todos.