Este fórum está sendo desativado

[Saulo]

Boa Tarde!
Atualmente são necessários Somar dados de várias células e após somatório, digitá-los em outras células como numa espécie de consolidação de dados, porém esse processo todo é de forma manual e permite margem de erro.
O Pedido de Ajuda: Que os dados das colunas: "I", "J", "K", "L", da planilha anexo, fossem consolidadas automaticamente pelo sistema.

Desde já agradeço.

[Estevaoba]

Se seu Excel for da versão 365, tente desta forma:

Delete os valores do intervalo I5para baixo e cole esta fórmula em I5:

Código: Selecionar todos

=ÚNICO($B$5:$B$26)

Faça o mesmo para K5 e cole esta fórmula:

Código: Selecionar todos

=ÚNICO($C$5:$C$26)

Em J5 use esta outra:

Código: Selecionar todos

=SOMASE(B$5:B$26;I5;$F$5:$F$26)

E na L5 esta:

Código: Selecionar todos

=SOMASE($C$5:$C$26;K5;$F$5:$F$26)

Copie para preencher as colunas.

Good luck!

[Saulo]

Prezado Estevaoba 19 Ago 2020 às 15:43
Meu Excel Não é Versão 365 é Versão 2010.
Se Possível Peço Que Avalie Outra Alternativa.
Atenciosamente

[Estevaoba]

Use estas fórmulas matriciais para listar valores únicos. Cole e confirme com Ctrl+Shift+Enter em vex de apenas Enter.
Em I5:

Código: Selecionar todos

=SEERRO(ÍNDICE($B$5:$B$26;CORRESP(1;(CONT.SE(I$4:I4;$B$5:$B$26)=0)*($B$5:$B$26<>"");0));"")

Em K5:

Código: Selecionar todos

=SEERRO(ÍNDICE($C$5:$C$26;CORRESP(1;(CONT.SE(K$4:K4;$C$5:$C$26)=0)*($C$5:$C$26<>"");0));"")

Copie para preencher as colunas.

Abraço

[Saulo]

Prezado Por Estevaoba 19 Ago 2020 às 17:10
Obrigado Por Dispor de Seu Tempo e Paciência Para Ajudar-me.
Funcionou Perfeitamente.
Só Mais Um Pedido, Caso Seja Possível, Note Que Na Planilha Possui Uma Aba "GRÁFICOS", onde pego dados da planilha "DADOS", Teria Como Automatizar Esses Gráficos de Forma que a cada inserção de novos dados ele se auto ajustaria de acordo com novos dados inseridos.
Desde Já agradeço.
OBS: Anexo Novamente a Planilha Já Contemplada Com Suas Soluções Anteriores

[Estevaoba]

Para o gráfico atualizar intervalos automaticamente, criei intervalos dinâmicos nomeados com a função DESLOC.
Veja os novos intervalos criados na aba Fórmula, Gerenciador de Nomes.
Para o intervalos Geracao, por exemplo, uso esta fórmula:

Código: Selecionar todos

=DESLOC(DADOS!$F$5;;;CONT.VALORES(DADOS!$F$5:$F$1000);1)

E no gráfico uso esses intervalos nomeados para os intervalos das séries.
Por exemplo, para a série Geração kW, clique direito no gráfico, entre em Selecionar Dados e botão Editar.
No campo Valores da série digite:
=DADOS!Geracao
Sem cedilha e til de propósito, pois algumas versões do Excel não admitem caracteres especiais em nomes de intervalos.
Modifiquei o seu primeiro gráfico com os intervalos que criei.
Favor conferir no anexo.

Ab.

[Saulo]

Prezado Estevaoba 19 Ago 2020 às 19:06
Muito Obrigado Por Ajudar-me!
Então....
A consolidação dos dados das colunas “I”, “J”, “K”, “L”, estão perfeitas, porém a atualização dos gráficos não funcionaram, observe que dados da semana (coluna “I”) e seus respectivos valores (coluna “J”), bem como dados do Mês (coluna “K”) e seus respectivos valores (coluna “L”) não atualizaram os gráficos na planilha “Grafico”.
O Mesmo problema se aplica ao gráfico diário que é abastecido com dados da colunas “A”, “F”, “G”.
OBS.: Lembrando que as entradas de dados nas colunas “A”, “D”, “E”, “F”, “G”, são dinâmicas, ou seja, sempre que houver fatos, esses serão digitados e automaticamente os gráficos deverão estarem preparados para receber novos dados.
Se possível peço vossa análise.
Ressalva: Anexo planilhas com dados atuais.
Atenciosamente

[Estevaoba]

Eu tinha criado intervalos dinâmicos apenas para o gráfico diário, o qual, quando abri, já estava atualizado com os valores da última data da coluna A.
Criei agora novos intervalos dinâmicos para os outros gráficos, usando também a função DESLOC, porém associada com a função CONT.SE, devido às fórmulas que existem nas colunas de dados:
Para o intervalo Media_Semana ficou assim:

Código: Selecionar todos

=DESLOC(DADOS!$J$5;;;CONT.SE(DADOS!$J$5:$J$10000;">"&0);1)

Segue planilha com os gráficos atualizados.

Ab.