Este fórum está sendo desativado

[Wieniawski]

Olá Amigos!

Preciso de uma ajuda com uma fórmula utilizando diversos "SES", porém não está dando certo, nesta parte:

SE(I2="Marítimo";SE(PROCV(Painel!D2;Agendados!AH:AH;1;0)<>"";"Agendado Carregamento"

Na coluna "J" do Painel, era para pegar a informação da aba "Agendados", e tendo o nº da ordem na coluna "AH", deveria assumir "Agendado Carregamento", porém não está acontecendo isso.

A planilha está em anexo.

Obrigado!!

Cockpit ME II.xlsm

[osvaldomp]

... deveria assumir "Agendado Carregamento", porém não está acontecendo isso.
E nunca irá acontecer.

A sua fórmula é inconsistente pois há 3 comparativos iguais ~~~> SE(I2="Marítimo".
Se I2 = Marítimo então sempre, sempre, sempre, a fórmula irá aplicar o PROCV() na planilha Cockpit e nunca na MB51 ou na Agendados.

=SEERRO(SE(I2="Rodoviário";PROCV(D2;Rodoviário!A:B;2;0);SE(I2="Marítimo";SE(PROCV(D2;Cockpit!A:K;11;0)<>"";"Faturado";SE(I2="Marítimo";SE(PROCV(D2;'MB51'!AI:AI;1;0)>1;"Estufado";SE(I2="Marítimo";SE(PROCV(Painel!D2;Agendados!AH:AH;1;0)<>"";"Agendado Carregamento";"")))))));"Aguardando")[/i]

Se você quer que o PROCV() seja aplicado na Agendados então exclua os dois primeiros comparativos SE(I2="Marítimo";...).

[Wieniawski]

Olá osvaldomp!

Seria assim?

=SEERRO(SE(I2="Rodoviário";PROCV(D2;Rodoviário!A:B;2;0);SE(PROCV(D2;Cockpit!A:K;11;0)<>"";"Faturado";SE(PROCV(D2;'MB51'!AI:AI;1;0)>1;"Estufado";SE(I2="Marítimo";SE(PROCV(Painel!D2;Agendados!AH:AH;1;0)<>"";"Agendado Carregamento";"")))));"")

[osvaldomp]

Olá, @Wieniawski .

Aparentemente não há erro.

Porém, se o resultado não for o esperado então explique com exatidão o que você quer que a fórmula retorne.

Me parece que I2 ou é Marítimo ou é Rodoviário, então descreva para cada um desses dois casos qual o resultado que você quer da fórmula em J2.

[Wieniawski]

Olá Osvaldomp, obrigado pelo retorno!

Isso mesmo coluna I vai ser marítimo ou rodoviário.

Se for rodoviário, vai pegar informação somente da aba rodoviário.

Se for marítimo, vai pegar informação das demais abas.

Está funcionando quando pega informação das abas Cockpit e MB51, porém não puxa a informação quando é da aba Agendados, como exemplo a ordem 25175182 (célula D33), ela aparece na aba agendados na coluna AH, o resultado na célula J33 da aba Painel, teria que ser "Agendado Carregamento", porém não é isso que está acontecendo.

abç

[osvaldomp]

Olá, @Wieniawski .

Experimente esta abaixo.

Código: Selecionar todos

=SE(OU(E(I2="Rodoviário";CONT.SE(Rodoviário!A:A;D2));E(I2="Marítimo";PROCV(D2;Cockpit!A:K;11;0)<>""));"Faturado";SE(E(I2="Marítimo";CONT.SE('MB51'!AI:AI;D2));"Estufado";SE(E(I2="Marítimo";CONT.SE(Agendados!AH:AH;D2));"Agendado Carregamento";"Aguardando")))

[Wieniawski]

Olá, @Wieniawski .

Experimente esta abaixo.

Código: Selecionar todos

=SE(OU(E(I2="Rodoviário";CONT.SE(Rodoviário!A:A;D2));E(I2="Marítimo";PROCV(D2;Cockpit!A:K;11;0)<>""));"Faturado";SE(E(I2="Marítimo";CONT.SE('MB51'!AI:AI;D2));"Estufado";SE(E(I2="Marítimo";CONT.SE(Agendados!AH:AH;D2));"Agendado Carregamento";"Aguardando")))

Olá Osvaldomp!

Deu certo! Muito obrigado por mais esta ajuda!

abraço!!