Este fórum está sendo desativado

[Newed]

Boa tarde pessoal.

Estou com uma dúvida para retornar os valores de uma planilha.
Seria mais ou menos o seguinte.
Possuo uma planilha com diversas avaliações, em alguns casos, um mesmo indivíduo é analisado por mais de um analista. Tanto com nota, quanto com comentários.

Sendo assim, na planilha modelo que envio em anexo, o que preciso é que quando eu selecione o indivíduo (célula F15), eu tenha na lista (em azul) todos os analistas que o avaliaram, quais foram as notas que eles deram e o que eles comentaram.

A minha dificuldade é justamente por se tratar de dados em várias colunas, já tentei com função ÍNDICE, CORRESPOND, etc., mas não consegui. Se puderem me ajudar, agradeço.

[Estevaoba]

Cole em E21 e copie para baixo.

Código: Selecionar todos

=SEERRO(ÍNDICE($B$6:$B$100;AGREGAR(15;6;LIN($B$6:$B$100)/(($C$6:$C$100=$F$15)*(CONT.SE(E$20:E20;$B$6:$B$100)=0));1)-LIN($B$6)+1);"")

Altere o primeiro intervalo ÍNDICE($B$6:$B$100 para as outras colunas.

Good luck!

[Newed]

Cole em E21 e copie para baixo.

Código: Selecionar todos

=SEERRO(ÍNDICE($B$6:$B$100;AGREGAR(15;6;LIN($B$6:$B$100)/(($C$6:$C$100=$F$15)*(CONT.SE(E$20:E20;$B$6:$B$100)=0));1)-LIN($B$6)+1);"")

Altere o primeiro intervalo ÍNDICE($B$6:$B$100 para as outras colunas.

Good luck!

Funcionou perfeitamente, só tive que fazer um ajuste para também retornar os dados da segunda avaliação, dessa forma, utilizei outra SEERRO para criar mais uma opção de busca (coluna F que também contem os indivíduos) e manter a possibilidade de ocultar dados de erro.

Contudo, tentei utilizar a mesma função no Google Sheets, e não consegui utilizar a função AGREGAR lá. Aparentemente ela nem existe no Sheets.

De qualquer forma, obrigado!
Vou continuar tentando encontrar alguma forma de realizar isso no Sheets. Caso alguém saiba como corrigir isso, agradeço!

Vlw!!!

[Estevaoba]

De nada. Fico feliz por poder ajudar.

Tem esta opção com a função MENOR, mas a fórmula é matricial.
Após colar ou editar, confirme com Ctrl+Shift+Enter em ves de Enter apenas.

Código: Selecionar todos

=SEERRO(ÍNDICE($B$6:$B$100;MENOR(SE($C$6:$C$100=$F$15;SE(CONT.SE(E$20:E20;$B$6:$B$100)=0;LIN($B$6:$B$100)-LIN($B$6)+1));1));"")

Ab.

[Newed]

Tentei utilizar essa nova fórmula, mas devo estar fazendo algo errado, pois está retornando o valor "0" e não foi por falta de tornar a fórmula matricial.

Estou enviando o link para um exemplo da planilha com a qual estou tento dificuldade.

https://docs.google.com/spreadsheets/d/ ... sp=sharing

A dificuldade é:
Quando eu selecionar o Gestor, deveria aparecer todos os colaboradores que o avaliaram, independente de ter sido avaliado como gestor 1 ou gestor 2.

O fato de ter Avaliação 1 e Avaliação 2 é porque alguns colaboradores possuem dois gestores e outros possuem um só.
Como é uma planilha que recebe as respostas através de formulário Google, então irá existir essas duas colunas de gestores avaliados.

Como se percebe, no gestor selecionado "SANDRA", deveria aparecer os colaboradores:
JOÃO (Avaliou a SANDRA como gestor 1)
MATHEUS (Avaliou a SANDRA como gestor 2)
CARLOS (Avaliou a SANDRA como gestor 1)
MANOEL(Avaliou a SANDRA como gestor 2)

[Estevaoba]

Você está usando uma fórmula diferente.
Segue a fórmula que postei antes, modificada para sua nova planilha. Cole em C15 como matricial e copie para baixo:

Código: Selecionar todos

=SEERRO(SEERRO(ÍNDICE($C$4:$C$9;MENOR(SE($D$4:$D$9=$E$12;SE(CONT.SE(C$14:C14;$C$4:$C$9)=0;LIN($C$4:$C$9)-LIN($C$4)+1));1));ÍNDICE($C$4:$C$9;MENOR(SE($G$4:$G$9=$E$12;SE(CONT.SE(C$14:C14;$C$4:$C$9)=0;LIN($C$4:$C$9)-LIN($C$4)+1));1)));"")

Ab.

[Kledison]

Olá!


outra opção seria:

Código: Selecionar todos

=QUERY(C4:I9;"SELECT C,E,F WHERE D = """&E12&""" OR G = """&E12&""" ")

Seguindo o exemplo do Google Planilhas que você postou, apague todas as fórmulas das células C15 a F20, depois cole a fórmula acima na célula C15, não precisa arrastar.




Att

[Newed]

Você está usando uma fórmula diferente.
Segue a fórmula que postei antes, modificada para sua nova planilha. Cole em C15 como matricial e copie para baixo:

Código: Selecionar todos

=SEERRO(SEERRO(ÍNDICE($C$4:$C$9;MENOR(SE($D$4:$D$9=$E$12;SE(CONT.SE(C$14:C14;$C$4:$C$9)=0;LIN($C$4:$C$9)-LIN($C$4)+1));1));ÍNDICE($C$4:$C$9;MENOR(SE($G$4:$G$9=$E$12;SE(CONT.SE(C$14:C14;$C$4:$C$9)=0;LIN($C$4:$C$9)-LIN($C$4)+1));1)));"")

Ab.

Funcionou! Só falta eu conseguir resolver o problema para as colunas de nota e observações, pois fiz as alterações que acreditei que seriam as necessárias para puxar esses dados, porém no caso das notas acontece algum problema quando duas notas se repetem, por exemplo, dois colaboradores com a nota 1, o segundo não aparece a nota.

[Newed]

Olá!


outra opção seria:

Código: Selecionar todos

=QUERY(C4:I9;"SELECT C,E,F WHERE D = """&E12&""" OR G = """&E12&""" ")

Seguindo o exemplo do Google Planilhas que você postou, apague todas as fórmulas das células C15 a F20, depois cole a fórmula acima na célula C15, não precisa arrastar.




Att

Também funcionou brother! Só encontrei uma inconsistência que não consegui resolver. Por exemplo, no caso, quando selecionamos SANDRA, os dados dos colaboradores são retornados de forma correta, porém, a nota do ultimo colaborador (MANOEL) que deveria ser 10 e a observação também OBS 10, acabem sendo retornados os valores da coluna E e F, no caso nota 6 e OBS 6.

Não sei como corrigir essa fórmula. Mas seria algo do tipo:
No intervalo dos dados selecionados, quando selecionarmos o gestor na célula E12, se houver referência a ele na coluna D, puxar os dados da coluna C, E e F (isso está na fórmula), mas se a referência à ele estiver na coluna G, puxar os dados das colunas C, H e I .


De qualquer forma, muito obrigado pela alternativa, independente de qualquer coisa, tudo é aprendizado. Vlw mesmo!

[Kledison]

@Newed!

Verifica com essa fórmula:

Código: Selecionar todos

={QUERY(C4:I9;"SELECT C,E,F WHERE D = """&E12&""" ");QUERY(C4:I9;"SELECT C,H,I WHERE G = """&E12&""" ")}

Att