Este fórum está sendo desativado

[JairJunior2]

Bom dia!
Preciso de uma macro que imprima a planilha em anexo de forma a não mostrar células vazias (""), quando mando imprimir esta saindo um montede páginas em branco, pois ele entende que tem a formula na célula

[mprudencio]

Afinal vc quer imprimir qual delas?

A que esta com o nome Impressão ou a Fluxo de dados?


Se for a impressão poste a planilha e nao a imagem dela.

[JairJunior2]

Eu preciso da planilha fluxo de gastos, a planilha impressão é so para mostrar como eu preciso que fique, para facilitar o entendimento

[mprudencio]

De qualquer maneria a imagem nao ajuda.

Poste tb a planilha impressão

[JairJunior2]

Eu só cliquei em ctrl p, na aba fluxo de gastos

[osvaldomp]

Você escreveu no resultado desejado:
"Impressão desejada com 2 paginas(neste caso) pegando todas linhas e colunas que tenham valores diferentes de vazio ("")"

No seu Bando de Dados a última coluna com valores diferentes de vazio é a coluna M, no entanto no resultado desejado você colocou a coluna J, o que contraria o critério que você descreveu acima. Explique.

[JairJunior2]

A última é a letra M mesmo, na página de impressão que não mostrei, desculpa. Ele vai aparecer na página 2 de 2

[osvaldomp]

Experimente:

Código: Selecionar todos

Sub Imprime()
 Dim r As Long, c As Long
  With ActiveSheet
   r = .Columns("A:A").Find("*", After:=.Range("A6"), searchdirection:=xlPrevious, LookIn:=xlValues).Row
   c = .Rows("2:2").Find("*", After:=.Range("A2"), searchdirection:=xlPrevious, LookIn:=xlValues).Column
   .PageSetup.PrintArea = "A1:" & Cells(r, c).Address(0, 0)
   '.PrintOut
  End With
End Sub

sugestão - rode o código para testar e se o resultado for o desejado remova o apóstrofo do início desta linha (em vermelho) '.PrintOut e rode o código novamente para imprimir

[JairJunior2]

Ele sintetizou as células em branco, porém a última do "total" não apareceu e tem alguma forma de voltar a mostrar tudo?

[osvaldomp]

... porém a última do "total" não apareceu ...

Onde você quer que aquela linha apareça ?

[JairJunior2]

Como última linha, apena para saber a soma daquela coluna. E sobre voltar a aparecer a planilha inteira?

[osvaldomp]

Vacilo meu pois a linha "total" aparece no seu resultado desejado

Veja se melhorou. Coloque os dois códigos abaixo em um mesmo módulo.
O segundo código limpa a área de impressão e reexibe as linhas.
Você pode rodá-los um por vez manualmente ou pode rodar o segundo automaticamente logo após imprimir, basta remover o apóstrofo da linha 'Reseta no primeiro código.

Código: Selecionar todos

Sub Imprime()
 Dim r As Long, c As Long, LR As Long
  With ActiveSheet
   r = .Columns("A:A").Find("*", After:=.Range("A6"), searchdirection:=xlPrevious, LookIn:=xlValues).Row
   c = .Rows("2:2").Find("*", After:=.Range("A2"), searchdirection:=xlPrevious, LookIn:=xlValues).Column
   LR = .Cells(Rows.Count, 1).End(3).Row
   .Rows(r + 1 & ":" & LR - 1).Hidden = True
   .PageSetup.PrintArea = "A1:" & Cells(LR, c).Address(0, 0)
   '.PrintOut
  End With
  'Reseta
End Sub


Sub Reseta()
 Dim LR As Long
 With ActiveSheet
  LR = .Cells(Rows.Count, 1).End(3).Row
  .Rows("7:" & LR).Hidden = False
  .PageSetup.PrintArea = ""
 End With
End Sub

[JairJunior2]

Vacilo meu pois a linha "total" aparece no seu resultado desejado

Veja se melhorou. Coloque os dois códigos abaixo em um mesmo módulo.
O segundo código limpa a área de impressão e reexibe as linhas.
Você pode rodá-los um por vez manualmente ou pode rodar o segundo automaticamente logo após imprimir, basta remover o apóstrofo da linha 'Reseta no primeiro código.

Código: Selecionar todos

Sub Imprime()
 Dim r As Long, c As Long, LR As Long
  With ActiveSheet
   r = .Columns("A:A").Find("*", After:=.Range("A6"), searchdirection:=xlPrevious, LookIn:=xlValues).Row
   c = .Rows("2:2").Find("*", After:=.Range("A2"), searchdirection:=xlPrevious, LookIn:=xlValues).Column
   LR = .Cells(Rows.Count, 1).End(3).Row
   .Rows(r + 1 & ":" & LR - 1).Hidden = True
   .PageSetup.PrintArea = "A1:" & Cells(LR, c).Address(0, 0)
   '.PrintOut
  End With
  'Reseta
End Sub


Sub Reseta()
 Dim LR As Long
 With ActiveSheet
  LR = .Cells(Rows.Count, 1).End(3).Row
  .Rows("7:" & LR).Hidden = False
  .PageSetup.PrintArea = ""
 End With
End Sub

Funcionou de mais!!! Obrigado