Este fórum está sendo desativado

[rslbrasil]

Pessoal
algum tem ou sabe se existe uma macro oculta
que sempre a abre o arquivo registra o usuário e modificações?

[felmback]

da uma olha da ai ...


GURU QUE FEZ ESSE .

[rslbrasil]

da uma olha da ai ...


GURU QUE FEZ ESSE .

está dando erro aqui

Public Sub Registrar(strAcao As String)
'aqui usando a ENVIRON para capturar nome do pc data e usuario
aStream.WriteText Now & vbTab
aStream.WriteText Environ("USERNAME") & vbTab
aStream.WriteText Environ("COMPUTERNAME") & vbTab
aStream.WriteText strAcao & vbCrLf
End Sub

[felmback]

boa tarde amigo , vc criou os modulos separados MODULO CLASSE e MODULO ,aquele modulo 1 pode excluir ..


Esse código tem que está no MODULO CLASSE.

Código: Selecionar todos

Option Explicit
Private aStream As ADODB.Stream
Private sAquivo As String

Private Sub Class_Initialize()

    Set aStream = New ADODB.Stream
    aStream.Open

End Sub
Private Sub Class_Terminate()
    aStream.Close
    Set aStream = Nothing
End Sub
Public Property Get Arquivo() As String: Arquivo = sAquivo: End Property
Public Property Let Arquivo(pArquivo As String)
    sAquivo = pArquivo
    If Dir(sAquivo) <> "" Then
    
        aStream.LoadFromFile sAquivo
        aStream.Position = aStream.Size
    
    End If
End Property
Public Sub Registrar(strAcao As String)
'aqui usando a ENVIRON para capturar nome do pc data e usuario
    aStream.WriteText Now & vbTab
    aStream.WriteText Environ("USERNAME") & vbTab
    aStream.WriteText Environ("COMPUTERNAME") & vbTab
    aStream.WriteText strAcao & vbCrLf
End Sub

Public Sub Salvar()
'salvar
    aStream.SaveToFile sAquivo, adSaveCreateOverWrite
    
End Sub

e esse no modulo normal

Código: Selecionar todos

Public Sub LOG(strAcao As String)

    Dim oLOG As cLOG
    Set oLOG = New cLOG
    
        With oLOG
                        'caminho da rede para salvar o log
            .Arquivo = "W:\Regional Centro Oeste\BRASILIA\SUPORTE TECNICO_BSA\FDT DO REPARO\2014\" & "testandoLog.txt"
            
            .Registrar strAcao
            .Salvar
              
                
    
    
        End With
    
    End Sub

para salvar o log na mesma pasta da planilha ..

PASTA_DE_TRABALHO

Código: Selecionar todos

Private Sub Workbook_BeforeClose(Cancel As Boolean)
LOG " Fechou a Planilha "
'aqui cria o tipo de log
End Sub


Private Sub Workbook_BeforeSave(ByVal SaveAsUI As Boolean, Cancel As Boolean)
LOG "Salvou a Pasta de Trabalho"

End Sub

Private Sub Workbook_NewSheet(ByVal Sh As Object)
LOG "Iseriu uma Planilha"
End Sub

Private Sub Workbook_Open()
LOG "Abriu a Pasta de Trabalho"
End Sub
[\code]

troca esse
 .Arquivo = "W:\Regional Centro Oeste\BRASILIA\SUPORTE TECNICO_BSA\FDT DO REPARO\2014\" & "testandoLog.txt"

por esse

'ThisWorkbook.Path & Application.PathSeparator & "log.txt" '----( essa linha de codigo salva o logo  na mesma pasta que a pasta de trabalho )