Página 1 de 1

ALTERNANDO EM LOOP AS MENSAGENS AS SEGUNDAS-FEIRAS

Enviado: 20 Jan 2023 às 16:55
por GENECI
Boa tarde!

Solicito a sua ajuda, conforme o arquivo anexo.

Grato.

Re: ALTERNANDO EM LOOP AS MENSAGENS AS SEGUNDAS-FEIRAS

Enviado: 20 Jan 2023 às 20:58
por Estevaoba
Boa noite.

Acredito que você terá uma tabela com as datas futuras e seus respectivos técnicos.
Assim, criei uma tabela com dados progressivos a partir dos dados iniciais e fiz a fórmula conforme solicitado.
Confira se atende.

Good luck!

Re: ALTERNANDO EM LOOP AS MENSAGENS AS SEGUNDAS-FEIRAS

Enviado: 21 Jan 2023 às 10:59
por GENECI
Bom dia! Estevaoba

Muito obrigado.

Devido a falta de espaço, não gostaria de alimentar a tabela para uma consulta posterior.
Gostaria de usar os nomes e as datas na própria fórmula, se não for possível, usar ama tabela auxiliar apenas uma vez e sem alterar os dados, como ponto da sequência, e a fórmula efetuar o cálculo.

Grato.

Re: ALTERNANDO EM LOOP AS MENSAGENS AS SEGUNDAS-FEIRAS

Enviado: 21 Jan 2023 às 13:53
por Estevaoba
Segue uma fórmula usando apenas as informações das células A1 e B1, e com matrizes virtuais criadas dentro das funções LET e SEQUÊNCIA, disponíveis na versão Excel 365 ou postrerior.
Código: Selecionar todos
=SEERRO("Técnico "&LET(Seg;DATA(ANO(A1);MÊS(A1);ESCOLHER(DIA.DA.SEMANA(DATA(ANO(A1);MÊS(A1);1));2;1;7;6;5;4;3));Pos;MOD(SEQUÊNCIA((B1-Seg)/7+1;1;1;1)-1;5)+1;Datas;SEQUÊNCIA((B1-Seg)/7+1;1;Seg;7);Tec;{"Paulo";"Luiz";"Silas";"Augusto";"Almir"};ÍNDICE(Tec;CORRESP(ÍNDICE(Pos;CORRESP(B1;Datas;0));Pos;0)));TEXTO(B1;"dddd")&" -  Não há visita Técnica")
Ab.

Re: ALTERNANDO EM LOOP AS MENSAGENS AS SEGUNDAS-FEIRAS

Enviado: 21 Jan 2023 às 15:21
por GENECI
Boa tarde!

Falta um pequeno ajuste para funcionar.
No Office 2016 não funcionou, tanto para fórmula convencional como matricial. Retorna a mensagem: O dia da semana - Não há visita técnica
Por favor, tem como incrementar a fórmula além das células A1 e B1 também as tabelas: F1:F5 e G1:G5

Grato.

Re: ALTERNANDO EM LOOP AS MENSAGENS AS SEGUNDAS-FEIRAS

Enviado: 21 Jan 2023 às 16:26
por Estevaoba
Consegui simplificar a fórmula, sem as funções do Excel 365 e sem usar a sua tabela F1:G5:
Código: Selecionar todos
=SE(DIA.DA.SEMANA(B1)=2;"Técnico "&ÍNDICE({"Paulo";"Luiz";"Silas";"Augusto";"Almir"};CORRESP(MOD(QUOCIENTE($B$1-DATA(ANO(A1);MÊS(A1);ESCOLHER(DIA.DA.SEMANA(DATA(ANO(A1);MÊS(A1);1));2;1;7;6;5;4;3));7);5)+1;LIN(A1:A5);0));TEXTO(B1;"dddd")&" -  Não há visita Técnica")
Ab.

Re: ALTERNANDO EM LOOP AS MENSAGENS AS SEGUNDAS-FEIRAS

Enviado: 23 Jan 2023 às 08:10
por GENECI
Bom dia!
Em definitivo apresentou a solução do problema, muito complexa a fórmula.
Grato.