Página 1 de 1
[RESOLVIDO] FÓRMULA QUE RETORNA VALOR DE CONDOMÍNIO POR SALA INDIVIDUALMENTE
Enviado: 10 Ago 2022 às 18:02
por SandroLima
Boa tarde, pessoal.
Tenho uma planilha com as Abas "PARTICIPAÇÃO" e "CONDOMÍNIO".
Na Aba "PARTICIPAÇÃO" tenho tabelas onde estão assinaladas o Mês em que cada cada sala participou de um determinado tipo de despesa.
E na Aba "CONDOMÍNIO tenho a tabela "TB_Condominio" onde estão informados os valores de cada despesa, a que grupo pertencem e o Mês em que ocorreram.
Preciso de ajuda para as fórmulas da tabela "TB_Condominio_RelConsolidado" onde gostaria que tivesse como resultado o valor correspondente ao condomínio de cada sala correlacionando a participação, o tipo de despesa e o Mês emq ue ocorreu.
No caso do Mês de Janeiro a conta fica fácil pois são R$ 3.076,03 de despesas e como todas as salas participaram de todas as despesas a conta fica da seguinte maneira:
3076,83/7 = 439,43
Cada sala ficou com o mesmo valor de condomínio
Mas há meses em que nem todas as salas participam das despesas.
Ou embora participem em determinado mês, podem não participar de todas as despesas.
Alguém poderia por gentileza me ajudar a desenvolver a fórmula para calcular isso considerando então a participação de cada sala, em cada tipo de despesa e a cada Mês?
Preciso com isso saber o valor de condomínio referente a cada sala mensalmente.
Segue planilha para verificação e testes.
Re: FÓRMULA QUE RETORNA VALOR DE CONDOMÍNIO POR SALA INDIVIDUALMENTE
Enviado: 10 Ago 2022 às 19:55
por Estevaoba
Criei uma tabela auxiliar a partir da célula B80 da aba participação para relacionar as salas relevantes.
E esta fórmula para distirbuir os valores nessas salas:
Código: Selecionar todos=$K6*ÍNDICE(PARTICIPAÇÃO!$C$80:$N$86;CORRESP(L$5;PARTICIPAÇÃO!$B$80:$B$86;0);CORRESP($E6;PARTICIPAÇÃO!$C$22:$N$22;0))/SOMA(ÍNDICE(PARTICIPAÇÃO!$C$80:$N$86;0;CORRESP($E6;PARTICIPAÇÃO!$C$22:$N$22;0)))
Veja se confere no anexo.
Good luck!
Re: FÓRMULA QUE RETORNA VALOR DE CONDOMÍNIO POR SALA INDIVIDUALMENTE
Enviado: 11 Ago 2022 às 22:01
por SandroLima
Boa noite, Stevaoba.
Obrigado pela ajuda... a ideia da tabela auxiliar foi ótima e a fórmula vou poder utilizar em outras aplicações.
Mas nesse momento o que preciso é diferente... Dessa forma ela divide o valor total em partes iguais entre as salas do condomínio que participaram das despesas em determinado mês.
Porém aqui está o X da questão... as salas que participam das despesas em um determinado mês participam de despesas específicas.
Por exemplo, no Mês de Maio a Sala 5 participou de todas as despesas, no entanto, no Mês de Junho a mesma sala 5 não participou das despesas dos Grupos(ou Tipos) 2 e 4.
Portanto o valor do condomínio não deve ser distribuído igualmente.
Não sei se consegui me fazer entender.
Re: FÓRMULA QUE RETORNA VALOR DE CONDOMÍNIO POR SALA INDIVIDUALMENTE
Enviado: 12 Ago 2022 às 00:40
por Estevaoba
Quais seriam os resultados esperados para as salas 5 e 6 nesse período que você citou, junho?
Re: FÓRMULA QUE RETORNA VALOR DE CONDOMÍNIO POR SALA INDIVIDUALMENTE
Enviado: 12 Ago 2022 às 14:20
por SandroLima
Boa tarde, Stevaoba.
Obrigado pela ajuda até aqui.
*** SALA 5 / MÊS JUNHO
No Mês de Junho a Sala 5 Participou das Despesas do Grupo 1 e 3 somente que totalizaram:
R$ 1.037,25 + R$ 0,00 = R$ 1.037,25 como pode ser visto na tabela "TB_Condominio_RelConsolidado".
No Mês de Junho participaram das despesas do Grupo 1 as salas:
Sala 1, Sala 5, Sala 6 e Sala 7
Ainda no Mês de Junho participaram das despesas do Grupo 3 as salas:
Sala 1, Sala 5 e Sala 6
Sendo assim a conta para a Sala 5 seria:
(1.037,25 / 4) + (0,00 / 3) = 259,31
*** SALA 6 / MÊS JUNHO
No Mês de Junho a Sala 6 participou de todos os grupos de despesa que totalizaram:
R$ 1.037,25 + R$ 2.528,71 + R$ 0,00 + R$ 147,00 = R$ 3.712,96 como pode ser visto na tabela "TB_Condominio_RelConsolidado".
No Mês de Junho participaram das despesas do Grupo 1 as salas:
Sala 1, Sala 5, Sala 6 e Sala 7
Ainda no Mês de Junho participaram das despesas do Grupo 2 as salas:
Sala 1 e Sala 6
Ainda no Mês de Junho participaram das despesas do Grupo 3 as salas:
Sala 1, Sala 5 e Sala 6
Ainda no Mês de Junho participaram das despesas do Grupo 4 as salas:
Sala 1 e Sala 6
Sendo assim a conta para a Sala 6 seria:
(1.037,25 / 4) + (2.528,71 / 2) + (0,00 / 3) + (147 / 2)
= 259,31 + 1264,35 + 0 + 73,5
= 1567,16
Portanto, para o Mês de Junho:
- Sala 5 = R$ 259,31
- Sala 6 = R$ 1567,16
Re: FÓRMULA QUE RETORNA VALOR DE CONDOMÍNIO POR SALA INDIVIDUALMENTE
Enviado: 12 Ago 2022 às 17:23
por Estevaoba
Boa tarde.
A fórmula ficou bem extensa para acomodar cada grupo de despesas. Cole em L6 e copie para a direita e para baixo:
Código: Selecionar todos=SOMA(ÍNDICE($G$6:$J$17;LINS($A$1:$A1);1)*SE(DESLOC(PARTICIPAÇÃO!$B$20;CORRESP(L$5;PARTICIPAÇÃO!$B$21:$B$69;0)+2;CORRESP($E6;PARTICIPAÇÃO!$C$22:$N$22;0))="X";1;0)/ÍNDICE(PARTICIPAÇÃO!$C$7:$F$18;CORRESP($E6;PARTICIPAÇÃO!$B$7:$B$18;0);1);ÍNDICE($G$6:$J$17;LINS($A$1:$A1);2)*SE(DESLOC(PARTICIPAÇÃO!$B$20;CORRESP(L$5;PARTICIPAÇÃO!$B$21:$B$69;0)+3;CORRESP($E6;PARTICIPAÇÃO!$C$22:$N$22;0))="X";1;0)/ÍNDICE(PARTICIPAÇÃO!$C$7:$F$18;CORRESP($E6;PARTICIPAÇÃO!$B$7:$B$18;0);2);ÍNDICE($G$6:$J$17;LINS($A$1:$A1);3)*SE(DESLOC(PARTICIPAÇÃO!$B$20;CORRESP(L$5;PARTICIPAÇÃO!$B$21:$B$69;0)+4;CORRESP($E6;PARTICIPAÇÃO!$C$22:$N$22;0))="X";1;0)/ÍNDICE(PARTICIPAÇÃO!$C$7:$F$18;CORRESP($E6;PARTICIPAÇÃO!$B$7:$B$18;0);3);ÍNDICE($G$6:$J$17;LINS($A$1:$A1);4)*SE(DESLOC(PARTICIPAÇÃO!$B$20;CORRESP(L$5;PARTICIPAÇÃO!$B$21:$B$69;0)+5;CORRESP($E6;PARTICIPAÇÃO!$C$22:$N$22;0))="X";1;0)/ÍNDICE(PARTICIPAÇÃO!$C$7:$F$18;CORRESP($E6;PARTICIPAÇÃO!$B$7:$B$18;0);4))
Nesta SOMA há quatro argumentos, um para cada grupo de despesas.
Cada argumento consiste de três componentes. Tomando como exemplo a fórmula em P11, Sala 5, mês junho, segue detalhamento do primeiro argumento (grupo de despesas 1):
ÍNDICE($G$6:$J$17;LINS($A$1:$A6);1)*SE(DESLOC(PARTICIPAÇÃO!$B$20;CORRESP(P$5;PARTICIPAÇÃO!$B$21:$B$69;0)+2;CORRESP($E11;PARTICIPAÇÃO!$C$22:$N$22;0))="X";1;0)/ÍNDICE(PARTICIPAÇÃO!$C$7:$F$18;CORRESP($E11;PARTICIPAÇÃO!$B$7:$B$18;0);1)
1. ÍNDICE($G$6:$J$17;LINS($A$1:$A6);1) - para encontrar o valor da despesa do grupo 1 em junho (1037,25)
2. *SE(DESLOC(PARTICIPAÇÃO!$B$20;CORRESP(P$5;PARTICIPAÇÃO!$B$21:$B$69;0)+2;CORRESP($E11;PARTICIPAÇÃO!$C$22:$N$22;0))="X";1;0) - para resultar 1 se a sala participou e zero se negativo. Esse resultado será multiplicado pelo valor encontrado no item 1.
3. /ÍNDICE(PARTICIPAÇÃO!$C$7:$F$18;CORRESP($E11;PARTICIPAÇÃO!$B$7:$B$18;0);1) - para encontrar quantas salas participaram desse grupo de despesas em junho. O valor resultante do item 2 será dividido pelo valor encontrado neste item.
Favor fazer testes e ver se atende.
Ab.
Re: FÓRMULA QUE RETORNA VALOR DE CONDOMÍNIO POR SALA INDIVIDUALMENTE
Enviado: 14 Ago 2022 às 17:39
por SandroLima
Excelente, Stevaoba!
Exatamente o que precisava. E olha que já quebrei a cabeça tentando montar a lógica de alguma fórmula para essa questão.
Já adaptei ela aqui na planilha original e funcionou perfeitamente.
Desmembrei a fórmula em linhas separadas para melhor entendimento dos cálculos envolvidos:
Código: Selecionar todos=SOMA(
ÍNDICE($G$6:$J$17;LINS($A$1:$A1);1)*SE(DESLOC(PARTICIPAÇÃO!$B$20;CORRESP(L$5;PARTICIPAÇÃO!$B$21:$B$69;0)+2;CORRESP($E6;PARTICIPAÇÃO!$C$22:$N$22;0))="X";1;0)/ÍNDICE(PARTICIPAÇÃO!$C$7:$F$18;CORRESP($E6;PARTICIPAÇÃO!$B$7:$B$18;0);1);
ÍNDICE($G$6:$J$17;LINS($A$1:$A1);2)*SE(DESLOC(PARTICIPAÇÃO!$B$20;CORRESP(L$5;PARTICIPAÇÃO!$B$21:$B$69;0)+3;CORRESP($E6;PARTICIPAÇÃO!$C$22:$N$22;0))="X";1;0)/ÍNDICE(PARTICIPAÇÃO!$C$7:$F$18;CORRESP($E6;PARTICIPAÇÃO!$B$7:$B$18;0);2);
ÍNDICE($G$6:$J$17;LINS($A$1:$A1);3)*SE(DESLOC(PARTICIPAÇÃO!$B$20;CORRESP(L$5;PARTICIPAÇÃO!$B$21:$B$69;0)+4;CORRESP($E6;PARTICIPAÇÃO!$C$22:$N$22;0))="X";1;0)/ÍNDICE(PARTICIPAÇÃO!$C$7:$F$18;CORRESP($E6;PARTICIPAÇÃO!$B$7:$B$18;0);3);
ÍNDICE($G$6:$J$17;LINS($A$1:$A1);4)*SE(DESLOC(PARTICIPAÇÃO!$B$20;CORRESP(L$5;PARTICIPAÇÃO!$B$21:$B$69;0)+5;CORRESP($E6;PARTICIPAÇÃO!$C$22:$N$22;0))="X";1;0)/ÍNDICE(PARTICIPAÇÃO!$C$7:$F$18;CORRESP($E6;PARTICIPAÇÃO!$B$7:$B$18;0);4))
Vou estudar ela aqui.
Muito obrigado de novo e tenha uma excelente semana.
Re: [RESOLVIDO] FÓRMULA QUE RETORNA VALOR DE CONDOMÍNIO POR SALA INDIVIDUALMENTE
Enviado: 14 Ago 2022 às 17:47
por Estevaoba
Boa tarde.
De nada, amigo. Fico feliz em ajudar.
Esqueci de dizer que com esta solução você não precisa daquela tabela auxiliar da fórmula anterior.
Ab.