Guru do Excel e Power BI

Enviado: **29 Jun 2021 às 10:48**

Pessoal, tudo bem?
Queria saber se vocês poderiam me ajudar com algo que estou tentando há um tempão.

Tenho uma planilha de cadastro de funcionários da empresa e as colunas que importam pra essa duvida:

Tipo de contrato: LOCAL
Data de Admissão: XX/XX/XXXX
Data de Desligamento: XX/XX/XXXX

Quero fazer uma relatório dos funcionários locais (pois tem estagiário e terceirizados também) que estavam na empresa para cada mês do ano (Janeiro, Fevereiro, Março...)

Criei uma tabela com os meses em cada coluna e tô tentando a formula:

=SUM(COUNT.SES(Table1[Contrato];"Local";Table1[Data Admissao];"<="&FIMMES(C9;0);Table1[Data Desligamento];">"&FIMMES(C9;0);Table1[Data Desligamento];""))

C9 é minha célula do mês correspondente.

O que estou pensando e tentando desenhar aí:

quero todo mundo que era Local + que foi admitido na empresa até o dia 31 daquele mês + não tenha sido demitido até o fim daquele mês ou não tenha sido demitido ainda. (quando não é demitido, a data de desligamento fica em branco)

Com isso espero conseguir o número de funcionários ativos naquele mês.

Mas não funciona....
Alguma ideia?

Obrigada desde já!!

Enviado: **29 Jun 2021 às 11:32**

Segue modelo em anexo.
Coloquei SUM ali em cima porque meu note da empresa usa o excel em inglês, esqueci na hora que traduzi.

No exemplo estou testando a formula.

Obrigada!!

Enviado: **29 Jun 2021 às 12:32**

Cole uma cópia da fórmula abaixo em B3, arraste até B4, arraste B3:B4 até M.

Código: Selecionar todos

=CONT.SES(Table1[[Contrato]:[Contrato]];$A3;Table1[[Data Admissao]:[Data Admissao]];"<="&FIMMÊS(B$2;0);Table1[[Data Desligamento]:[Data Desligamento]];">"&FIMMÊS(B$2;0))
ou
=COUNTIFS(Table1[[Contrato]:[Contrato]],$A3,Table1[[Data Admissao]:[Data Admissao]],"<="&EOMONTH(B$2,0),Table1[[Data Desligamento]:[Data Desligamento]],">"&EOMONTH(B$2,0))

#
Corrija a grafia em B5 da Sheet1, deve ser igual a A4 da Sheet2.

Enviado: **29 Jun 2021 às 14:03**

Oi Osvaldo,

O problema é que na formúla eu não estou contando aqueles que estão com a data de desligamento em branco. Ou seja, pessoas ainda ativas na empresa; então no final eu não tenho o pessoal que está ativo mesmo.
Assim eu conto apenas quem tem alguma data de desligamento escrita. É esse o problema que estou tendo.

Obrigada mais uma vez!

Enviado: **29 Jun 2021 às 18:55**

Olá, Jéssica.

Entendi. Nesse caso é preciso dobrar a fórmula para acrescentar mais essa condição (desligamento em branco) ou utilizar SOMARPRODUTO().

Código: Selecionar todos

=SOMA(CONT.SES(Table1[[Contrato]:[Contrato]];$A3;Table1[[Data Admissao]:[Data Admissao]];"<="&FIMMÊS(B$2;0);Table1[[Data Desligamento]:[Data Desligamento]];">"&FIMMÊS(B$2;0));CONT.SES(Table1[[Contrato]:[Contrato]];$A3;Table1[[Data Admissao]:[Data Admissao]];"<="&FIMMÊS(B$2;0);Table1[[Data Desligamento]:[Data Desligamento]];""))
ou
=SOMARPRODUTO((Table1[[Contrato]:[Contrato]]=$A3)*(Table1[[Data Admissao]:[Data Admissao]]<=FIMMÊS(B$2;0))*((Table1[[Data Desligamento]:[Data Desligamento]]>FIMMÊS(B$2;0))+(Table1[[Data Desligamento]:[Data Desligamento]]="")))

#

Código: Selecionar todos

=SUM(COUNTIFS(Table1[[Contrato]:[Contrato]],$A3,Table1[[Data Admissao]:[Data Admissao]],"<="&EOMONTH(B$2,0),Table1[[Data Desligamento]:[Data Desligamento]],">"&EOMONTH(B$2,0)),COUNTIFS(Table1[[Contrato]:[Contrato]],$A3,Table1[[Data Admissao]:[Data Admissao]],"<="&EOMONTH(B$2,0),Table1[[Data Desligamento]:[Data Desligamento]],""))
or
=SUMPRODUCT((Table1[[Contrato]:[Contrato]]=$A3)*(Table1[[Data Admissao]:[Data Admissao]]<=EOMONTH(B$2,0))*((Table1[[Data Desligamento]:[Data Desligamento]]>EOMONTH(B$2,0))+(Table1[[Data Desligamento]:[Data Desligamento]]="")))

Enviado: **30 Jun 2021 às 13:39**

Muito obrigada, Osvaldo, deu certo e acabou com uma grande dor de cabeça minha!

Obrigada mesmo!!

Guru do Excel e Power BI

Formula CONT.SES

Formula CONT.SES

Re: Formula CONT.SES

Re: Formula CONT.SES

Re: Formula CONT.SES

Re: Formula CONT.SES

Re: Formula CONT.SES