Este fórum está sendo desativado

[AnaGalveias]

Boas,

Preciso de uma ajuda a escrever uma fórmula SE, o que quero é numa tabela se tudo estiver =X me devolva OK caso contrário NOK.
Envio a tabela em anexo a quem me puder ajudar, são várias colunas, o que queria é se nas colunas de "OK" estiver tudo com X me devolve OK noutra célula caso contrário NOK.

Obrigada desde já a quem me possa ajudar.

[MarcilioLobao]

AnaGalveias, Bom dia.

A função SE não é apropriada para fazer essa pesquisa sozinha.

Use-a com o auxílio da função CONT.SE.

Basta uma pequena alteração na sua fórmula original.

DE.........: =SE( B9:B40="X"; "OK"; "NOK" )
PARA.....: =SE(CONT.SE( B9:B40;"<>X") = 0; "OK"; "NOK")

Agora a fórmula pergunta se alguma célula no intervalo de B9:B40 é diferente de X.

Era isso o que você queria?
Eu espero ter ajudado.

Contagem-de-X.xlsx

[AnaGalveias]

Obrigada, vou testar

[AnaGalveias]

@MarcilioLobao,
Não está a dar resultado, e eu também queria para abranger várias colunas e também não dá.

[JCabral]

Experimente usar:

Código: Selecionar todos

=SE(SOMARPRODUTO(--($B$9:$B$40<>"X"));"NOK";"OK")

[Deciog]

AnaGalveias, Bom Dia.

Estou confuso, confere se desta forma que voce quer, se não for, explica melhor

Usa esta formula

=SE(E($B$9:$B$40="X";$D$9:$D$40="X";$F$9:$F$40="X";$H$9:$H$40="X";$J$9:$J$40="X");"OK";"NOK")

Se minha resposta foi útil, clique em obrigado é uma forma de agradecimento da ajuda

Decio

[AnaGalveias]

@JCabral,
Ok, consegui para uma coluna com esta fórmula e para várias colunas?

[AnaGalveias]

@Deciog,
Com esta fórmula não me devolve nada aparece: #VALOR

[osvaldomp]

Código: Selecionar todos

=SE(CONT.SE(B9:J40;"X")=160;"OK";"NOK")

#
ou

Código: Selecionar todos

=SE(SOMARPRODUTO((B9:J40="X")*(MOD(COL(B9:J40);2)=0))=160;"OK";"NOK")

[AnaGalveias]

@osvaldomp,

Não funcionam as fórmulas

[Kledison]

@AnaGalveias !

Qual seria o resultado esperado? Ambas fórmulas do Osvaldo e Décio funcionam ,ou seja, caso alguma coluna não tenha o X aparece NOK.




Att

[osvaldomp]

... o que quero é numa tabela se tudo estiver =X me devolva OK caso contrário NOK.
... são várias colunas, o que queria é se nas colunas de "OK" estiver tudo com X me devolve OK noutra célula caso contrário NOK.

Veja o seu arquivo anexo com as duas fórmulas que passei funcionando corretamente com base nos critérios acima.
#

Função SE-1.xlsx

[AnaGalveias]

@osvaldomp,
Já vi e realmente já consegui, contudo se eu quiser acrescentar ou tirar linhas vou ter que alterar o número certo? já não seria 160.

Nota: não sei o porquê de não ter conseguido inicialmente

[osvaldomp]

@osvaldomp,
... se eu quiser acrescentar ou tirar linhas vou ter que alterar o número certo? já não seria 160.
Vou tentar adivinhar o que você realmente quer: a quantidade de linhas com "X" a ser verificada será em função da quantidade de Peças lançadas na coluna A. Por exemplo, se A contiver dados até a linha 13 então você quer que a fórmula verifique a quantidade de "X" da linha 9 até a linha 13. Por outro lado, se A estiver preenchida até a linha 25 então a fórmula deveria contar "X" da linha 9 até a 25. É isso? Se sim, que tipo de conteúdo será colocado na coluna A? Forneça dois ou três exemplos.

Nota: não sei o porquê de não ter conseguido inicialmente
Relax, Excel is funny

[AnaGalveias]

@osvaldomp,

É isso mesmo que eu quero
Ficheiro com exemplos.

[osvaldomp]

#
Esta fórmula é mais simples do que a segunda abaixo porém ela tem uma restrição pois considera todas as colunas de B a J, por isso se o usuário colocar "X" em alguma das colunas que tenha cabeçalho "Data" a fórmula não retornará o resultado desejado.

Código: Selecionar todos

=SE((CONT.SE(A:A;"<>")-1)*5=CONT.SE(DESLOC(B9;;;CONT.SE(A:A;"<>")-1;9);"X");"OK";"NOK")

#
Esta outra considera somente as colunas com cabeçalho "OK".

Código: Selecionar todos

=SE((CONT.SE(A:A;"<>")-1)*5=SOMARPRODUTO((DESLOC(B9;;;CONT.SE(A:A;"<>")-1;9)="X")*(MOD(COL(B9:J9);2)=0));"OK";"NOK")

[JCabral]

Bem sei que depois de uma solução do Osvaldo, não deveria colocar aqui nada, mas consegui esta solução, menos clean que a solução do Osvaldo.

Código: Selecionar todos

=SE(SOMARPRODUTO((DESLOCAMENTO(Folha1!$B$9;0;0;CONTAR.VAL(Folha1!$A$9:$A$100);9)="X")*(RESTO(COL($B$9:$J$9);2)=0))=(LINS(DESLOCAMENTO(Folha1!$A$9;0;0;CONTAR.VAL(Folha1!$A$9:$A$100);1)))*5;"OK";"NOK")

[AnaGalveias]

@osvaldomp,

Não consigo usar as fórmulas, não sei porquê, aparece #NOME?

[AnaGalveias]

@JCabral,

Com a sua fórmula já consegui fazer o que queria.

Obrigada

[osvaldomp]

@osvaldomp,
Não consigo usar as fórmulas, não sei porquê, aparece #NOME?

Algumas funções do Excel têm sintaxe diferente entre as versões Português-BR e Português-PT, por isso você precisa fazer as conversões. Compare com a fórmula que o Jorge (@JCabral ) postou e veja as sintaxes correspondentes à sua versão.

No arquivo que postei antes com as fórmulas, estas funcionaram aí porque ao abrir o arquivo o Excel automaticamente converteu as fórmulas para a sua versão.