Página 1 de 1
Proxima Data com base em dias
Enviado: 15 Out 2020 às 12:32
por rit
Bom dia,
Eu pensei em uma tabela onde tem um data final do mes X e em uma coluna existe um tempo em dias Y, eu preciso que com base nessa data final do mês X + tempo em dias Y me traga a proxima data Z.
Exemplo:
Meu mes termina no dia 30 (x) meu tempo em dias é 15 (y) e minha proxima data no outro mês é no dia 17 (z)
Eu precisaria que mostrasse o Z, preciso de uma formula para isso, nao existe uma tabela montada aceito sujestões de formato..
Re: Proxima Data com base em dias
Enviado: 16 Out 2020 às 02:53
por Estevaoba
=FIMMÊS(qualquer data do mês em questão;0)+Tempo Y
Good luck!
Re: Proxima Data com base em dias
Enviado: 21 Out 2020 às 10:38
por rit
Como faço um procv para me trazer a ultima data com base em uma condição e com base no mes que eu escolher?
A - 10/10/2020
A - 28/10/2020
A - 20/11/2020
Preciso que se a condição for A ele me traga o dia 28/10/2020.. e ai com essa data depois eu farei uma conta com mais 15 dias por exemplo e ele me traga a data mais proxima que no caso seria dia 20/11/2020 (sempre arredondando pra cima) seriam duas colunas, duas informações diferentes.
Re: Proxima Data com base em dias
Enviado: 21 Out 2020 às 15:52
por Estevaoba
Para facilitar a elaboração e teste de soluções, favor postar um modelo com algumas linhas da sua planilha, colocando manualmente os resultados esperados e explicando o critério adotado.
Ab.
Re: Proxima Data com base em dias
Enviado: 22 Out 2020 às 09:49
por jmarcelosp
adicionando uma dúvida neste questão, que além da data do final do mês, mas que me traga somente dia util da semana, exemplo mês 10/2020
Último dia util será dia 30/10, pois o dia 31/10 será um sádado
Grato
Re: Proxima Data com base em dias
Enviado: 22 Out 2020 às 15:26
por osvaldomp
1. retorna a data do último dia útil do mês atual
=DIATRABALHO(FIMMÊS(HOJE();0)+1;-1)
2. retorna a data do último dia útil do mês que corresponde à data inserida em A1
=DIATRABALHO(FIMMÊS(A1;0)+1;-1)
3. retorna a data do último dia útil do mês atual acrescido de 10 dias úteis
=DIATRABALHO(DIATRABALHO(FIMMÊS(HOJE();0)+1;-1);10)
4. retorna a data do último dia útil do mês que corresponde à data inserida em A1, acrescido de 10 dias úteis
=DIATRABALHO(DIATRABALHO(FIMMÊS(A1;0)+1;-1);10)
5. retorna a data do último dia útil do mês que corresponde à data inserida em A1 acrescido dos dias úteis inseridos em B1
=DIATRABALHO(DIATRABALHO(FIMMÊS(A1;0)+1;-1);B1)
obs. acrescente o intervalo com os feriados, se for o caso ~~~> =DIATRABALHO(data inicial;dias;[intervaloFeriados])
Re: Proxima Data com base em dias
Enviado: 22 Out 2020 às 16:36
por rit
Boa tarde,
Segue anexo exemplo do que eu precisaria.
talvez seja mais complexo do que pensei, mas acredito que com formulas pode ser resolvido.
Re: Proxima Data com base em dias
Enviado: 22 Out 2020 às 17:17
por Estevaoba
Se o seu Excel for versão 365, use estas fórmulas:
Em D10:
Código: Selecionar todos=MÁXIMOSES(C2:C6;C2:C6;">="&DATA(ANO(C2);A10;1);C2:C6;"<="&FIMMÊS(DATA(ANO(C2);A10;1);0))
Em E10:
Código: Selecionar todos=MÍNIMOSES(C2:C6;C2:C6;">="&MÁXIMOSES(C2:C6;C2:C6;">="&DATA(ANO(C2);A10;1);C2:C6;"<="&FIMMÊS(DATA(ANO(C2);A10;1);0))+C10)
Se for versão anterior:
Use esta em D10:
Código: Selecionar todos=MÁXIMO(SE(C2:C6>=DATA(ANO(C2);A10;1);SE(C2:C6<=FIMMÊS(DATA(ANO(C2);A10;1);0);C2:C6)))
E esta em E10:
Código: Selecionar todos=MÍNIMO(SE(C2:C6>=MÁXIMO(SE(C2:C6>=DATA(ANO(C2);A10;1);SE(C2:C6<=FIMMÊS(DATA(ANO(C2);A10;1);0);C2:C6)))+C10;C2:C6))
As duas últimas fórmulas são matriciais. Cole e confirme com Ctrl+Shift+Enter em vez de apenas Enter.
Ab.
Re: Proxima Data com base em dias
Enviado: 26 Out 2020 às 09:21
por rit
Bom dia,
Muito bom as formulas obrigado por estar ajudando, mas ainda se eu quiser encaixar essas formulas em um tipo de procv? que a condição seja "A" ?
Re: Proxima Data com base em dias
Enviado: 26 Out 2020 às 12:46
por Estevaoba
Qual a versão do seu Excel?
Re: Proxima Data com base em dias
Enviado: 26 Out 2020 às 12:56
por Estevaoba
Supondo que seja versão 2019 ou 365, em D10 a fórmula ficaria assim:
Código: Selecionar todos=MÁXIMOSES(C2:C6;B2:B6;B10;C2:C6;">="&DATA(ANO(C2);A10;1);C2:C6;"<="&FIMMÊS(DATA(ANO(C2);A10;1);0))
e em E10:
Código: Selecionar todos=MÍNIMOSES(C2:C6;B2:B6;B10;C2:C6;">="&MÁXIMOSES(C2:C6;B2:B6;B10;C2:C6;">="&DATA(ANO(C2);A10;1);C2:C6;"<="&FIMMÊS(DATA(ANO(C2);A10;1);0))+C10)
Ab.