Guru do Excel e Power BI

Amigos boa noite!

Voltei! Mais cedo o amigo @sandman ajudou-me com uma fórmula, contudo quando comecei a incluir os argumentos ( são 21) deu pau!

Preciso de ajuda com a seguinte fórmula:

=SE(E($BB$4="AL";$G$8>0);$H$8+J8;SE(E($BB$4="BA";$G$8>0);$H$8+L8;SE(E($BB$4="CE";$G$8>0);$H$8+N8;SE(E($BB$4="DF";$G$8>0);$H$8+P8;SE(E($BB$4="ES";$G$8>0);$H$8+R8;SE(E($BB$4="GO";$G$8>0);$H$8+T8;SE(E($BB$4="MA";$G$8>0);$H$8+V8;SE(E($BB$4="MG";$G$8>0);$H$8+X8;SE(E($BB$4="MS";$G$8>0);$H$8+Z8;SE(E($BB$4="MT";$G$8>0);$H$8+AB8;SE(E($BB$4="PA";$G$8>0);$H$8+AD8;SE(E($BB$4="PE";$G$8>0);$H$8+AF8;SE(E($BB$4="PI";$G$8>0);$H$8+AH8;SE(E($BB$4="PR";$G$8>0);$H$8+AJ8;SE(E($BB$4="RJ";$G$8>0);$H$8+AL8;SE(E($BB$4="RN";$G$8>0);$H$8+AN8;SE(E($BB$4="RR";$G$8>0);$H$8+AQ8;SE(E($BB$4="RS";$G$8>0);$H$8+AR8;SE(E($BB$4="SC";$G$8>0);$H$8+AT8;SE(E($BB$4="SE";$G$8>0);$H$8+AV8;SE(E($BB$4="TO";$G$8>0);$H$8+AX8;0)))))))))))))))))))))

Abs,

Renato

primeiro adicione as informações
al , es, ba, ...
na linha 4 da tabela nas colunas correspondentes "de onde vai pegar os dados"
depois use essa formula
=SE($G$8>0;ÍNDICE($J8:$AY8;CORRESP($BB$4;$J$4:$AY$4;0))+$H$8;0)

Prezado @edcronos ou sou muito burro ou não a fórmula não fecha! Tô acreditando que a primeira opção é a correta!

Continuo tentando...

SE(E($BB$4="AL";$G$8>0);$H$8+J8;
SE(E($BB$4="BA";$G$8>0);$H$8+L8;
SE(E($BB$4="CE";$G$8>0);$H$8+N8;
SE(E($BB$4="DF";$G$8>0);$H$8+P8;
SE(E($BB$4="ES";$G$8>0);$H$8+R8;
SE(E($BB$4="GO";$G$8>0);$H$8+T8;
SE(E($BB$4="MA";$G$8>0);$H$8+V8;
SE(E($BB$4="MG";$G$8>0);$H$8+X8;
SE(E($BB$4="MS";$G$8>0);$H$8+Z8;
SE(E($BB$4="MT";$G$8>0);$H$8+AB8;
SE(E($BB$4="PA";$G$8>0);$H$8+AD8;
SE(E($BB$4="PE";$G$8>0);$H$8+AF8;
SE(E($BB$4="PI";$G$8>0);$H$8+AH8;
SE(E($BB$4="PR";$G$8>0);$H$8+AJ8;
SE(E($BB$4="RJ";$G$8>0);$H$8+AL8;
SE(E($BB$4="RN";$G$8>0);$H$8+AN8;
SE(E($BB$4="RR";$G$8>0);$H$8+AQ8;
SE(E($BB$4="RS";$G$8>0);$H$8+AR8;
SE(E($BB$4="SC";$G$8>0);$H$8+AT8;
SE(E($BB$4="SE";$G$8>0);$H$8+AV8;
SE(E($BB$4="TO";$G$8>0);$H$8+AX8; 0)))))))))))))))))))))


como pode ver sua formula pouco muda

=SE ( $G$8>0 ; ÍNDICE( $J8:$AY8 ; CORRESP( $BB$4 ; $J$4:$AY$4 ; 0 )) + $H$8;0)
se $G$8>0
pegar valor que entre j8 e ay8 que na linha 4 a coluna tenha um valor = $BB$4 e some com $H$8

eu não sei onde tem que ficar essa formula, eu apenas segui a logica da sua
mas vc tem que colocar AL--BA-CE--...--SE--TO na linha 4 onde a formula vai pegar as informaç~;oes
essa linha vai ser comparada com $BB$4

mas para falar a verdade eu aconselho a vc a estudar um pouco mais de excel e formulas antes de tentar pegar trabalhos onde um erro de calculo ou de informação pode levar a falência
isso falo pq oq estamos entendendo da sua explicação pode não ser exatamente oq vc imagina e e pequenas discrepancias nos valores pode levar a atitudes erroneas nos negocios

@Edcronos muitissimo obrigado! Deu certo, estava cometendo um erro! Grande abraço.