Este fórum está sendo desativado

[SOUZADENILSON]

Boa tarde. Preciso descobrir a maior e a menor data utilizando um criterio, caso o criterio utilizado nao seja encontrada sata a celula fica vazia.
Essas data serao procuradas em outra guia.
A formula que utilizei qdo a data nao foi encontrada retornou como 01/01/1900

[SOUZADENILSON]

Segue arquivo em anexo

[Estevaoba]

Boa noite.

Em B4:
=SEERRO(SE(É.NÃO.DISP(CORRESP($B$1;Plan_Base!$C$4:$C$100;0));"";MÍNIMO(SE((Plan_Base!$C$4:$C$100=$B$1);Plan_Base!$D$4:$D$100)));" ")

Como a sua planilha tem abas com o nome dos colaboradores, você pode usar esta fórmula em B4 e arrastar para baixo para exibir as datas dos outros colaboradores:
=SEERRO(SE(É.NÃO.DISP(CORRESP($B$1;INDIRETO("'"&$A3&"'!C4:C100");0));"";MÍNIMO(SE((INDIRETO("'"&$A3&"'!C4:C100")=$B$1);INDIRETO("'"&$A3&"'!D4:D100"))));" ")

E se estiver usando o Excel 365 ou posterior, use a função MÍNIMOSES e a fórmula ficaria:
=SEERRO(SE(É.NÃO.DISP(CORRESP($B$1;INDIRETO("'"&$A3&"'!C4:C100");0));"";MÍNIMOSES(INDIRETO("'"&$A3&"'!D4:D100");INDIRETO("'"&$A3&"'!C4:C100");$B$1));" ")

Good luck!

[SOUZADENILSON]

Em B4:
=SEERRO(SE(É.NÃO.DISP(CORRESP($B$1;Plan_Base!$C$4:$C$100;0));"";MÍNIMO(SE((Plan_Base!$C$4:$C$100=$B$1);Plan_Base!$D$4:$D$100)));" ")

Esta funcionou.
Tentei colocar no lugar da desta parte Plan_Base!$C$4:$C$100 esta entre parentese (Plan_Base!C4:C) onde c4 é a primeira linha e não especificar a ultima linha para o calculo, porém deu erro

[Estevaoba]

Não entendi a sua dúvida.
De qualquer forma, segue a sua planilha com as fórmulas montadas de modo que você possa arrastar para baixo quando tiver mais abas de colaboradores.

Ab.

[SOUZADENILSON]

Caso os dados ultrapasse a linha 100 a formula nao calcula

[Estevaoba]

Boa tarde.
O intervalo que usei é só um exemplo.
Ajuste-o conforme a sua realidade.

Ab.

[Strogonoff]

Caro Denílson, Boa Noite!
se a planilha está totalmente dedicada a esse controle, use a coluna toda como referência
ficando sua fórmula assim:
=MÍNIMO(SE((A:A =G4);D:D))
se o sistema não for muito gigante rodará bem...
Tem outras fórmulas para agregar o último valor que é a função cont..valores, mas acho que para seu caso e para o seu tipo de problema, seria muita mão de obra para algo simples..
Espero ter ajudado.
Abraço
PS: Mandei a planilha em anexo para eventuais dúvidas.