Guru do Excel + Power BI

[Dunguinha]

Boa noite.
Na pasta de trabalho em anexo preciso que a palavra digitada na TextBox1 seja encontrada na planilha e a todas as linhas que contém a palavra seja selecionada.
Não precisa deletar, só selecionar.

[osvaldomp]

Código: Selecionar todos

Private Sub CommandButton1_Click()
 Dim c As Range, cR As String
  For Each c In Range("D3:D" & Cells(Rows.Count, 4).End(3).Row)
   If c.Value = TextBox1.Value Then
    cR = cR & c.Address & ","
   End If
  Next c
  If cR <> "" Then
   Range(Left(cR, Len(cR) - 1)).EntireRow.Select
  Else: [A1].Activate: MsgBox "NOME NÃO ENCOTRADO"
  End If
End Sub

[Dunguinha]

Muito obrigado Osvaldo, era isso mesmo que precisava.

[Dunguinha]

Ao adaptar o código para meu projeto deu erro.
Teria que selecionar várias linhas com a palavra buscada, pelo menos até linha 500
Pelo que percebi só vai até a linha 40 ou 43 e depois dá erro.
Exemplo em anexo.

[osvaldomp]

Teria que selecionar várias linhas com a palavra buscada, pelo menos até linha 500
Antes você postou um exemplo contendo 11 linhas com dados e só agora vem dizer que vai processar 500 linhas.
Habitue-se a passar as informações precisas logo na primeira postagem.

Código: Selecionar todos

Private Sub CommandButton1_Click()
 Dim c As Range, cR As Range
  For Each c In Range("D3:D" & Cells(Rows.Count, 4).End(3).Row)
   If c.Value = TextBox1.Value Then
    If Not cR Is Nothing Then
     Set cR = Union(cR, c.EntireRow)
    Else: Set cR = c.EntireRow
    End If
   End If
  Next c
  If Not cR Is Nothing Then
   cR.Select
  Else: [A1].Activate: MsgBox "NOME NÃO ENCONTRADO"
  End If
End Sub

[Dunguinha]

Desculpe Osvaldo, você tem razão. O projeto será para filtrar chaves de acessos de arquivos xml importados para o excel. Fiz muitos testes mas com xml de poucos itens. Agora apareceu essa necessidade. Obrigado pelo seu empenho mais uma vez.