Este fórum está sendo desativado

[fernnandocreed]

Fala galera, tudo bom?

É o seguinte, preciso de uma ajuda para fazer somatórias, porém com algumas condicionais.

Nas colunas COLABORADORES e R$ VALORES, preciso fazer uma soma apenas dos textos exclusivos da coluna VERSÃO e separadamente por serviço (coluna SERVIÇO), que pode ser 0 ou 1.

Os resultados das somas devem ser:

COLABORADORES
SOMA SERVIÇO 1: célula C1143 = 384.637
SOMA SERVIÇO 2: célula C1145 = 384.637

R$ VALORES
SOMA SERVIÇO 1: célula D1143 = R$ 6.384.208,69
SOMA SERVIÇO 2: célula D1145 = R$ 6.384.208,69

O arquivo está anexado

Se faltou alguma informação, é só falar... que tentarei explicar melhor.

Grato

[osvaldomp]

... soma apenas dos textos exclusivos da coluna VERSÃO
Não há valores exclusivos na coluna VERSÃO, pois TODOS os valores são repetidos.
Considerei que você quer somar os repetidos apenas uma vez.


e separadamente por serviço (coluna SERVIÇO), que pode ser 0 ou 1.
É desnecessário incluir a coluna SERVIÇO no critério da soma pois os valores para serviço 0 e serviço 1 SEMPRE serão iguais.

Código: Selecionar todos

=SOMARPRODUTO((A2:A1141<>"")/CONT.SE(A2:A1141;A2:A1141&"");C2:C1141)
=SOMARPRODUTO((A2:A1141<>"")/CONT.SE(A2:A1141;A2:A1141&"");D2:D1141)

#
curiosidade: porque você colocou na coluna A ~~~> ="0279/003" em lugar de colocar simplesmente 0279/003; para excluir o sinal de igual e as aspas ~~~> selecione A2:A1141 | Copiar | Colar Especial | Valores

[fernnandocreed]

Oi Osvaldo, obrigado pela resposta

Sim, não existem valores exclusivos, me expressei mal. Na verdade a soma tem que pegar apenas uma ocorrência de cada versão, então, se a versão 0279/003 ocorre 4 vezes, deve-se somar apenas uma vez o valor correspondente... e isso para todas as outras, a versão 0242/002 se repete 6x, mas o valor relacionado só deve ser somado uma vez.

Quanto ao SERVIÇO, neste exemplo, de fato os valores estão idênticos, mas na verdade ele irão variar no futuro, por isso preciso que esta condição tb seja considerada.

Com relação ao formato dos dados em versão, nem me atentei a isso, pois já vem do sistema assim, de qualquer forma, sua solução copiar e colar é bem vinda.

[osvaldomp]

Quanto ao SERVIÇO, neste exemplo, de fato os valores estão idênticos, mas na verdade ele irão variar no futuro, por isso preciso que esta condição tb seja considerada.

Olá, Fernando.
Veja se as fórmulas abaixo atendem. Acrescentei o critério SERVIÇO O / SERVIÇO 1.
Se não houver na tabela ao menos um SERVIÇO O e um SERVIÇO 1 para cada VERSÃO então a fórmula retornará erro.
Se as fórmulas não atenderem a todas as situações então eu sugiro que você disponibilize uma nova planilha com alguns dados somente (10 a 15 linhas) que contenham TODAS as variações possíveis de ocorrerem e coloque os resultados desejados.
#
COLABORADORES & SERVIÇO 0 e 1

Código: Selecionar todos

=SOMARPRODUTO((A2:A1141<>"")*(B2:B1141=0)/CONT.SES(A2:A1141;A2:A1141&"";B2:B1141;0);C2:C1141)
=SOMARPRODUTO((A2:A1141<>"")*(B2:B1141=1)/CONT.SES(A2:A1141;A2:A1141&"";B2:B1141;1);C2:C1141)

#
#
VALORES & SERVIÇO 0 e 1

Código: Selecionar todos

=SOMARPRODUTO((A2:A1141<>"")*(B2:B1141=0)/CONT.SES(A2:A1141;A2:A1141&"";B2:B1141;0);D2:D1141)
=SOMARPRODUTO((A2:A1141<>"")*(B2:B1141=1)/CONT.SES(A2:A1141;A2:A1141&"";B2:B1141;1);D2:D1141)

[fernnandocreed]

Cara, se atende? rs... era exatamente o que precisava, não sei como fez isso, mas resolveu o problema, muito obrigado mesmo.

Forte abraço.