Este fórum está sendo desativado

[Draki]

saudações a todos

preciso criar uma pesquisa em uma planilha, onde eu consiga ter múltiplos resultados de retorno
o PROCV simples não me ajuda, ou pelo menos não sei como usar de forma eficiente.

https://ibb.co/2vQpG83

acima o link de um exemplo bem simples que montei para explicar o que eu quero

eu tenho uma tabela 5x5 por exemplo, quero procurar um valor, tanto faz se será na linha 1 ou coluna 1 da tabela
esse valor quando encontrado, se for na linha 1 por exemplo, vai me trazer até 5 retornos de acordo com as linhas abaixo dele.
se eu estiver procurando pelo elemento FOGO por exemplo, quero que a pesquisa retorne todas as células que estiverem preenchidas com a palavra GREEN
basicamente é isso que quero fazer.

a idealização dessa planilha é algo bem maior, em torno de umas 40-50 variáveis e quando pesquisar uma quero retornar ordenado cada uma das variantes.
não tenho problema em fazer um campo de retorno para cada variação do que estiver preenchido nas células, será até melhor separado.
e onde eu uso nome de cores, já é definido que serão no máximo três categorias diferentes a serem preenchidas no decorrer da tabela.

espero ter sido claro e desde já muito obrigado pela atenção de todos.

[Estevaoba]

Você não colocou os resultados esperados, então fiz como acho ser o que você pretende.
Na célula que exibe o erro #N/D, cole esta fórmula matricial e, caso o seu Excel seja anterior a 2019, confirme com Ctrl+Shift+Enter em vez de apenas Enter:

Código: Selecionar todos

=SEERRO(ÍNDICE($B$1:$F$1;MENOR(SE(ÍNDICE($B$2:$F$6;CORRESP("FOGO";$A$2:$A$6;0);0)="GREEN";COL($B$1:$F$1)-COLS($A$1:$B$1)+1);LIN($Z1)));"")

Na fórmula, eu considero os dados no intervalo A1:F6. Ajuste os intervalos para a sua realidade.
Substitua os textos entre aspas por referência a células com esses textos para poder arrastar a fórmula para baixo e para a direita. A célula que contém "FOGO" você trava coluna e linha, por exemplo, $A$1. Já a que contém "GREEN", trave somente a linha, por exemplo, A$1.

Good luck!

[Draki]

olá @Estevaoba, muito obrigado pela ajuda.

funcionou exatamente como eu queria.

se não for pedir demais, você poderia me explicar os argumentos utilizados na fórmula?
eu criei uma planilha do zero para utilizar o intervalo de pesquisa A1:F6 como você mencionou

eu entendi mais ou menos o que você fez até o CORRESP
buguei no COL-COLS e estou sem entender o LIN travado no Z1

desculpe a ignorância e mais uma vez muito obrigado por me ajudar

[Estevaoba]

De nada. Fico feliz em ajudar.

MENOR(SE(ÍNDICE($B$2:$F$6;CORRESP("FOGO";$A$2:$A$6;0);0)="GREEN";COL($B$1:$F$1)-COLS($A$1:$B$1)+1);LIN($Z1))
A função MENOR é para buscar a menor coluna do intervalo COL($B$1:$F$1) que satisfaz a condição ="GREEN". A menor tem o k = 1, então uso o argumento LIN($Z1) que é igual a 1 e ao ser arrastado para baixo, passa a ser LIN($Z2), etc. A trava é só de coluna e tem apenas efeito estético, para não passar para LIN($AA1), LIN($AB1), etc ao arrastar para a direita.
-COLS($A$1:$B$1)+1 é para determinar onde começa o intervalo, no caso, na coluna B. Pode substituir por uma constante -1, pois -COLS($A$1:$B$1)+1=-1. Caso precise que inicie em outra coluna, digamos a C, seria -COLS($A$1:$C$1)+1, ou pela constante -2.
ÍNDICE($B$2:$F$6;CORRESP("FOGO";$A$2:$A$6;0);0) determina a linha correta a buscar na tabela, referente a FOGO, no caso. O zero no final para definir Nr de coluna faz a função ÍNDICE trazer todo o intervalo de B a F na linha predeterminada pela CORRESP.

Ab.