Este fórum está sendo desativado

[VictorSantos]

Boa tarde,

É possível criar uma auto numeração onde onde ela reinicie quando muda o mês, estou usando a formula =LIN(C2)& "-" & TEXTO(MÊS(C2);"00") & DIREITA(ANO(C2);"2") mais ela não reinicia quando o mês muda.

[Estevaoba]

Boa noite.

Tente:
=TEXTO(C2;"dd-mm-aa")
Ou
=DIA(C2)& "-" & TEXTO(MÊS(C2);"00") & "-" & DIREITA(ANO(C2);2)

Se não funcionar, e para facilitar a criação e teste de fórmulas, favor postar um modelo da sua planilha, colocando manualmente os resultados esperados e explicando os critérios usados para chegar neles.
Clique em +Resposta, Adicionar um anexo, adicionar arquivos.

Ab.

[VictorSantos]

Bom dia,

Obrigado pelo retorno, mais essas formulas não faz o que estou querendo, para facilitar o entendimento em anexo segue a planilha com o exemplo do resultado que estou tentando obter, se você ou alguém puder me ajudar fico agradecido.

[Estevaoba]

Em C2, copiado para baixo:

Código: Selecionar todos

=TEXTO(CONT.SES(B$2:B2;">="&DATA(ANO(B2);MÊS(B2);1);B$2:B2;"<="&FIMMÊS(DATA(ANO(B2);MÊS(B2);1);0));"00#")& "-" & TEXTO(MÊS(B2);"00") & DIREITA(ANO(B2);2)

Good luck!

[VictorSantos]

Obrigado fera, funcionou perfeito. .

Não achei uma forma de colocar esse assunto como concluído então editei o titulo

[VictorSantos]

Em C2, copiado para baixo:

Código: Selecionar todos

=TEXTO(CONT.SES(B$2:B2;">="&DATA(ANO(B2);MÊS(B2);1);B$2:B2;"<="&FIMMÊS(DATA(ANO(B2);MÊS(B2);1);0));"00#")& "-" & TEXTO(MÊS(B2);"00") & DIREITA(ANO(B2);2)

Good luck!

Fera, encontrei uma dificuldade na utilização dessa formula em uma tabela, essa formula funciona bem se eu ficar arrastando, porem se utilizo em uma tabela, quando adiciono um novo registro a numeração fica se repetindo, as informações que preenche essa planilha vem do form. devia ter mencionado isso antes.

[Estevaoba]

Nesse caso, seria interessante você postar um arquivo contendo um modelo da sua tabela simulando uma situação em que o erro ocorre, para podermos pensar em uma nova abordagem.
Ab.

[VictorSantos]

Bom dia,

Segue o arquivo com a tabela, se você adicionar uma data abaixo da ultima ele repete a numeração.

[osvaldomp]

No primeiro arquivo que você postou os dados estão no formato Intervalo, por isso a fórmula foi elaborada para funcionar em Intervalo, no entanto, conforme o segundo arquivo, o que você quer é uma fórmula para funcionar com dados no formato Tabela Excel .
Tabela Excel utiliza referências estruturadas, diferentemente de Intervalo.
Segue abaixo a fórmula do Mestre @Estevaoba com referências estruturadas.

Código: Selecionar todos

=TEXTO(CONT.SES(ÍNDICE([Hora de início];1;1):[@[Hora de início]];">="&DATA(ANO([@[Hora de início]]);MÊS([@[Hora de início]]);1);ÍNDICE([Hora de início];1;1):[@[Hora de início]];"<="&FIMMÊS(DATA(ANO([@[Hora de início]]);MÊS([@[Hora de início]]);1);0));"00#")& "-" & TEXTO(MÊS([@[Hora de início]]);"00") & DIREITA(ANO([@[Hora de início]]);2)

[VictorSantos]

No primeiro arquivo que você postou os dados estão no formato Intervalo, por isso a fórmula foi elaborada para funcionar em Intervalo, no entanto, conforme o segundo arquivo, o que você quer é uma fórmula para funcionar com dados no formato Tabela Excel .
Tabela Excel utiliza referências estruturadas, diferentemente de Intervalo.
Segue abaixo a fórmula do Mestre @Estevaoba com referências estruturadas.

Código: Selecionar todos

=TEXTO(CONT.SES(ÍNDICE([Hora de início];1;1):[@[Hora de início]];">="&DATA(ANO([@[Hora de início]]);MÊS([@[Hora de início]]);1);ÍNDICE([Hora de início];1;1):[@[Hora de início]];"<="&FIMMÊS(DATA(ANO([@[Hora de início]]);MÊS([@[Hora de início]]);1);0));"00#")& "-" & TEXTO(MÊS([@[Hora de início]]);"00") & DIREITA(ANO([@[Hora de início]]);2)

Entendi, agora está perfeito, muito obrigado pela ajuda.

Obs. Juro que não encontrei o botão para marcar como resolvido , vou altera o titulo.