Dúvidas sobre cálculos, funções simples e aninhadas, fórmulas matriciais, etc.
Por NiltonASantos
#64623
Bom dia.

Estou desenvolvendo uma planilha para Folha de Pagamento e preciso que, ao entrar com o valor do salário bruto, o excel automaticamente calcule o valor do INSS, com a alíquota e respectiva parcela à deduzir, com base na tabela informada.

Lembrando que a tabela de INSS trabalha com faixas. Então, por exemplo, caso o salário fosse de R$ 2.348,52, ele deve verificar que este valor está na faixa compreendida entre R$ 2.203,49 e R$ 3.305,22. Sendo assim, ele deve aplicar 12% em cima do valor bruto e, após, deduzir a alíquota referente, ou seja, R$ 82,60.

Então, o cálculo deve ser este

2.384,52 x 12% = 286,14
286,14-82,60 = 203,54

Portanto, o INSS deste funcionário será de R$ 203,54

Dada a tabela em anexo, como posso automatizar estes cálculos? Tentei com o PROCV e com o INDICE CORRESP mas não consegui.

Att.

Nilton
Você não está autorizado a ver ou baixar esse anexo.
Por osvaldomp
#64625
Código: Selecionar todos
=SE(B2<G7;SOMARPRODUTO(--(B2>{0;1100;2203,48;3305,22}); (B2-{0;1100;2203,48;3305,22}); {0,075;0,015;0,03;0,02});751,97)
NiltonASantos agradeceu por isso
Por NiltonASantos
#64626
"osvaldomp", agradeço pela resposta. Entretanto, percebi que você coloca os valores diretamente na fórmula. Como estes valores podem mudar, eu preciso que seja feito com o endereço da célula.

No futuro, esta planilha, vai para pessoas que poderão não saber mexer com fórmulas (além do perigo de alterarem e corromperem tudo) e seria muito mais prático que elas apenas alterassem os valores nas células correspondentes e o excel efetuassem os cálculos.

Será que há alguma forma de fazer isso?

Att.

Nilton
Por osvaldomp
#64646
Experimente:
Código: Selecionar todos
=MÍNIMO(B2;G4)*H4/100+MÍNIMO(B2-G4;G5-G4)*H5/100*(B2>G4)+MÍNIMO(B2-G5;G6-G5)*H6/100*(B2>G5)+MÍNIMO(B2-G6;G7-G6)*H7/100*(B2>G6)
A fórmula acima e a fórmula que passei no post anterior não utilizam a coluna auxiliar Parcela a deduzir.
#
Código: Selecionar todos
=SE(B2<=G4;B2*H4/100;SE(B2>G7;G7*H7/100-I7;B2*ÍNDICE(H4:H7;CORRESP(B2;F4:F7;1))/100-ÍNDICE(I4:I7;CORRESP(B2;F4:F7;1))))
A fórmula acima utiliza a coluna auxiliar Parcela a deduzir e o resultado deverá ser igual às duas fórmulas anteriores.
NiltonASantos agradeceu por isso
Por NiltonASantos
#64653
Bom dia Osvaldo.

As duas fórmulas funcionaram perfeitamente.

Gostaria apenas de solicitar gentilmente que me esclarecesse as diferenças entre as duas fórmulas. Percebi que, na primeira, não usa nem a coluna Mínimo nem a Parcela à Deduzir, enquanto que, na segunda, utiliza todas as colunas, mas não utiliza as células F5 e F6. O mais intrigante (pelo menos para mim) é que o resultado de ambas as fórmulas é o mesmo.

Poderia me explicar esta diferença, para eu poder aprender um pouco mais?

Mais uma vez, agradeço.

Abs.

Nilton
Por osvaldomp
#64658
Olá, Nilton.

Há duas formas para calcular o valor da contribuição. Esse cálculo é do tipo "cumulativo por faixa", semelhante ao utilizado no Carnê Leão e também para calcular comissão "cumulativa" sobre vendas.

forma1. verificar o quanto do salário de contribuição se enquadra em cada faixa da tabela, aplicar o percentual correspondente e ao final obter a soma. É a forma que utilizei na primeira fórmula do meu post anterior, e

forma2. verificar direto em que faixa da tabela se enquadra o salário de contribuição, aplicar o percentual correspondente e subtrair os valores correspondentes às faixas anteriores. Para facilitar, calcularam os valores a serem subtraídos das faixas anteriores e com eles formaram a coluna "Parcela a Deduzir" (sem acento no "a"). Veja a segunda fórmula do meu post anterior.

"... nem a Parcela à Deduzir, " ---> na forma2 de cálculo que comentei acima, se você aplicar o percentual direto conforme a faixa de enquadramento o cálculo está incorreto, pois há faixas anteriores com taxação menor. Um exemplo: salário contribuição 2.200,00, com base no enquadramento direto aplica-se 9%, porém a faixa anterior manda aplicar 7,5%, então será preciso subtrair o que foi calculado a mais, ou seja (9% - 7,5%) = 1,5%. Então o valor calculado a mais em relação à faixa anterior é ~~~> (1.100,00 x 1,5%) = 16,50. Os demais valores da coluna Parcela a Deduzir são obtidos dessa forma. Esta foi a forma que você utilizou no exemplo do seu primeiro post.

" ... enquanto que, na segunda, utiliza todas as colunas, mas não utiliza as células F5 e F6." ~~~> as células F5 e F6 estão contidas no intervalo F4:F7 ~~~> CORRESP(B2;F4:F7;1) ;)

Para acompanhar como as fórmulas funcionam: selecione a célula que contém a fórmula | menu Fórmulas | Avaliar Fórmula.

Outro modo: na Barra de fórmulas selecione a parte da fórmula de interesse e aperte F9, Esc para sair.
Editado pela última vez por osvaldomp em 16 Mai 2021 às 13:48, em um total de 1 vez.
NiltonASantos agradeceu por isso

Boa tarde! Gostaria de uma Help do grupo, uma fun[…]

TIRAR CONTAGEM DO ZERO

O erro é originado na fórmula da col[…]

Somatório de letras e ano

Caro Foxtri, Desculpe, fui no gerenciamento nome[…]

Eu sou novo no Power BI estou fazendo um dashboa[…]

Calcular saldo acumulado

Ola tudo bem? nao encontrei o anexo

Veja o anexo e faça as adaptaç&otild[…]

EDITAR CÓDIGO

Pessoal, boa noite!! Por favor preciso de uma ajud[…]

Excluir linhas com critério

solução manua l 1. selecione qu[…]