Dúvidas sobre cálculos, funções simples e aninhadas, fórmulas matriciais, etc.
  • Avatar do usuário
Por pfrodrigo
#63387
Olá.
Gostaria de uma ajuda para um planilha em anexo.
Seria para um lançamento muito grande, sequencial, nas 3 primeiras colunas, contendo um código, um nome e um local;
Tendo a necessidade de fazer o lançamento automático conforme o local e tendo uma classificação repetida;

Muito obrigado,
Deus abençoe.

Rodrigo
Você não está autorizado a ver ou baixar esse anexo.
#63399
Em E2, I2 e M2 (copiar/colar):
Código: Selecionar todos
=SEERRO(MENOR(ÍNDICE($A$2:$A$1000;CORRESP(DESLOC($G$1;;QUOCIENTE(COLS($A$1:A$1)-1;4)*4);$C$1:$C$1000;0)):ÍNDICE($A$2:$A$1000;SEERRO(CORRESP(DESLOC($K$1;;QUOCIENTE(COLS($A$1:A$1)-1;4)*4);$C$1:$C$1000;0)-1;CONT.VALORES($A$2:$A$1000)));LIN($A1));"")
Em F2 e arrastar para G2:
Código: Selecionar todos
=SEERRO(ÍNDICE(B$2:B$1000;CORRESP(E2;A$2:A$1000;0));"")
Ajustar CORRESP(E2; para CORRESP(I2; para a tabela seguinte, etc
Copiar para baixo.

Good luck!
#63408
Muito obrigado Estevaoba.
Deu certo. Deus te abençoe.

Só um detalhe para aperfeiçoar a planilha: caso eu queira deixar a classificação pela casa da rua X, casa da rua Y e casa da rua Z (3ª coluna de cada), como colocaria a organização na fórmula?
#63409
De nada, amigo. Prazer em poder ajudar.
Não entendi.
As fórmulas valem para as três tabelas.
Cole a primeira em E2. Copie de E2 e cole em I2. Repita para M2.
Favor conferir no anexo.

Ab.
Você não está autorizado a ver ou baixar esse anexo.
#63420
Valeu Estevão. Obrigado.

Não consegui classificar pela coluna da casa. Se a tabela for gigante, por exemplo, e eu quiser organizar por quem mora na casa 101, depois na 102, 103, etc.
A tabela que enviou está classificada pelo código de pesquisa.

Em outras palavras, quero saber em ordem naquela tabela quem mora na casa 101 (João, Maria, Joazinho e Mariazinha), na casa 102 (José, Josefa e Zezinho); 103 (Paulo e Paula); 104...

Abraço
#63421
OK, entendi.
Qual a sua versão de Excel?
Se for o 365, você conta com funções modernas, por exemplo, ÚNICO e CLASSIFICAR que facilitam esse tipo de trabalho.
Se for anterior, teria que usar fórmulas matriciais, o que pode causar lentidão no processamento.
Vou ver aqui possíveis soluções.
Mas preciso que você faça um modelo ou layout de como deseja a listagem.
#63425
Meu excel ainda é o 2013. Preciso atualizar.

O que fizer já está ótimo, irmão.
Seria só uma reclassificação mesmo, como se fosse um recortar e colar particionado.
É que a lista inicial (completa e sequencial) ficará muito grande e quero que jogue nas respectivas (automaticamente sem ter que recortar e colar) listas particionadas por rua/casa.
A ideia inicial era assim:
casa 101 da rua x
(jogar automaticamente os moradores aqui, independente de ser 1, 2, 3... moradores)

casa 102 da rua x
(jogar automaticamente os moradores aqui, independente de ser 1, 2, 3... moradores)

casa 101 da rua y
(jogar automaticamente os moradores aqui, independente de ser 1, 2, 3... moradores)
etc

Muito obrigado.
Abraço
#63429
Criei uma coluna auxiliar J repetindo o texto de C1 na primeira linha e com esta fórmula em J2, copiada para baixo:
Código: Selecionar todos
=SE(C2="";"";SE(ÉNÚM(LOCALIZAR("rua";C2));C2;J1))
Esta fórmula procura a palavra "rua" na coluna C e quando encontra, copia o texto de C para J. Quando não encontra, as linhas com Nr de casas, repete o texto da linha anterior. Isto serve para indexar as casas conforme a rua. Mas só vai funcionar se encontrar a palavra "rua", conforme o seu modelo.

No intervalo L1:O1, listei manualmente os títulos CASA DA RUA X, CASA DA RUA Y, etc. Poderia fazer com fórmula, porém matricial, e ficaria ainda mais lenta a planilha. Daí as vantagens do Excel 365.
Para cada CASA DA RUA listo as casas Nr com esta fórmula matricial em L2, copiada até Z2 e para baixo copiei até a linha 100:
Código: Selecionar todos
=SEERRO(ÍNDICE($C$2:$C$1000;CORRESP(1;(CONT.SE(L$1:L1;$C$2:$C$1000)=0)*($C$2:$C$1000<>"")*($J$2:$J$1000=L$1);0));" ")
Em G1 uso Validação de dados para selecionar CASA DA RUA usando esta fórmula, que lista as casas rua listadas no intervalos L1:Z1:
Código: Selecionar todos
=DESLOC($L$1;;;1;CONT.VALORES($L$1:$Z$1))
Em G2 uso Validação de dados para selecionar Casa Nr usando esta fórmula, que lista as casas Nr listadas no intervalos L2:Z100, conforme a casa rua selecionada em G1:
Código: Selecionar todos
=DESLOC($K$2;;CORRESP($G$1;$L$1:$Z$1;0);CONT.SE(ÍNDICE($L$2:$Z$100;0;CORRESP($G$1;$L$1:$Z$1;0));"<> ");1)
Em E2, copiado para F2 e para baixo, uso esta outra fórmula matricial para listar códigos e pessoas:
Código: Selecionar todos
=SEERRO(ÍNDICE(A$2:A$1000;MENOR(SE($J$2:$J$1000=$G$1;SE($C$2:$C$1000=$G$2;LIN($A$2:$A$1000)-LIN($A$2)+1));LINS($A1:$A$1)));" ")
Atente para as fórmulas matriciais acima. Depois de editar, confirme com Ctrl+Shift+Enter em vez de Enter apenas.
Confira no anexo se atende.

Ab.
Você não está autorizado a ver ou baixar esse anexo.

Bom dia! No ficheiro "Indicadores de Cronogr[…]

EXPE.TEXTO-PEGAR O ZERO

Boa noite, babdallas!! Tudo bom? Perfeito, era i[…]

Porcentagem em das porcentagens

=MÉDIA(A1:A6)

Perdão, anexei o arquivo errado sem querer.[…]

Oi gente tudo bem eu estou fazendo uma planilha on[…]

Pessoal, boa tarde!! Tenho uma planilha de horas […]

Boa tarde!! Alguém sabe uma fórmula[…]

Boa tarde!! Alguém consegue me ajuda com u[…]